[Помогите!] Рабочий скрипт для кликермана

[benn1]

Доброго времени суток, жуки!
В виду того, что вышла обнова.. или это вышло по совсем другим обстоятельствам, я не нашел полноценно рабочий скрипт на коробки! на сегодняшний день более менее , это скрипт "Корабль" - он просто клацает по миникарте, а петьку включая вручную- собирает за ним.
Так вот, поделитесь рабочим скриптом. Спасибо.

[E.x.p.r.e.s.s.]

Цитата: Сообщение от benn1 Доброго времени суток, жуки! В виду того, что вышла обнова.. или это вышло по совсем другим обстоятельствам, я не нашел полноценно рабочий скрипт на коробки! на сегодняшний день более менее , это скрипт "Корабль" - он просто клацает по миникарте, а петьку включая вручную- собирает за ним. Так вот, поделитесь рабочим скриптом. Спасибо.

    // подпрограмма обязательно выше вызова
    SUB(mouse_move,$MOVE_END_X,$MOVE_END_Y)   
       $MOVE_Start_X = $_xmouse
       $MOVE_Start_Y = $_ymouse
       $MOVE_X = $MOVE_Start_X
       $MOVE_Y = $MOVE_Start_Y
     
       $dist = DIST($MOVE_END_X,$MOVE_END_Y,$MOVE_Start_X,$MOVE_Start_Y)
       $MOVE_step = ($dist-1)/INT(SQRT($dist))
       $MOVE_X_step = ($MOVE_END_X-$MOVE_Start_X)/$MOVE_step
       $MOVE_Y_step = ($MOVE_END_Y-$MOVE_Start_Y)/$MOVE_step
     
       FOR($MOVE_i=0, $MOVE_i < INT($MOVE_step))
          $MOVE_X = $MOVE_X + $MOVE_X_step
          $MOVE_Y = $MOVE_Y + $MOVE_Y_step
          MOVE(INT($MOVE_X) + RND(-2,2), INT($MOVE_Y) + RND(-2,2))
          WAITMS($rnwait) // задержка при движении по точкам
       END_CYC   
    END_SUB
     
    SUB(m_move,$M_X,$M_Y)
       $rnwait = RND(2,4) // случайная скорость
       $MOVE_MID_X = INT(($_xmouse+$M_X)/2)
       $MOVE_MID_Y = INT(($_ymouse+$M_Y)/2)
       $otx = INT(ABS($_xmouse - $M_X) * 0.12)
       $oty = INT(ABS($_ymouse - $M_Y) * 0.12)
       mouse_move($MOVE_MID_X+RND(-$otx,$otx), $MOVE_MID_Y+RND(-$oty,$oty))
       mouse_move($M_X,$M_Y)
       MOVE($M_X,$M_Y)		//Передвинуть окончательно в заданную точку
    END_SUB
     
     
    //LOGCLEAR     
    //$MS = $_ms // засекаем время
    //LDOWN($_xmouse,$_ymouse) // рисуем
    //m_move(500,500) // передвигаем
    //LUP(500,500) // отпускаем
    //LOGWRITE ($_ms-$MS, " - ", $rnwait)     
    //HALT

#include "m_move.cms"
#name "DarkOrbit v1.1"
//=============================================

// область поиска
$x_1 = 0
$y_1 = 112
$x_2 = 1585
$y_2 = 844

// область мини карты
$x_mini_1 = 1418
$y_mini_1 = 711
$x_mini_2 = 1464
$y_mini_2 = 746

//=============================================

$cent_x=int(($x_2-$x_1)/2)
$cent_y=int(($y_2-$y_1)/2)
start:

// рандомный клик по миникарте
$rx = RND($x_mini_1,$x_mini_2)
$ry = RND($y_mini_1,$y_mini_2)

//INC($key_count,1)
//SWITCH($key_count)
//CASE(1)
//$rx = 1406+RND(-3,3)
//$ry = RND(-3,3)+713
//CASE(2)
//$rx = 1538+RND(-3,3)
//$ry = RND(-3,3)+719
//CASE(3)
//$rx = 1519+RND(-3,3)
//$ry = RND(-2,2)+804
//CASE(4)
//$rx = 1425+RND(-3,3)
//$ry = RND(-2,2)+801
//$key_count = 0
//DEFAULT
//END_SWITCH
M_MOVE($rx,$ry)
LCLICK($_xmouse,$_ymouse)
$check = 0
$check_out = 0
WHILE($check_out = 0)
GETSCREEN($x_1,$y_1, $x_2+1,$y_2+1)
COLORMODE(3,$x_1,$y_1, $x_2,$y_2)
IF_PIXEL_IN($x_1,$y_1, $x_2,$y_2,8376319,13101055)
   $x=0
   $y=0
   SCANPXL($arr,$x_1,$y_1, $x_2,$y_2,8376319)
   SCANPXL($arr,$x_1,$y_1, $x_2,$y_2,13101055)
   FOR($a=0,$a<ARRSIZE($arr),2)
      IF(DIST($arr[$a],$arr[$a+1],$cent_x,$cent_y)<DIST($x,$y,$cent_x,$cent_y))
         $x=$arr[$a]
         $y=$arr[$a+1]
      END_IF
   END_CYC
   UNDEFINE($arr)
   M_MOVE($x,$y)
   LCLICK($_xmouse,$_ymouse)
   WAITMS(RND(1700,1800))
   $check = 1
ELSE
   IF($check = 1)
      $check = 0
      M_MOVE($rx,$ry)
      LCLICK($_xmouse,$_ymouse)
      WAITMS(RND(100,350))
   ELSE
      GETSCREEN
      COLORMODE(6)
      IF((PXL($rx,$ry) = 8355711)&(PXL($rx,$ry) = 8355711))
         $check_out = 1
      ELSE
         GETSCREEN
         IF_PICTURE_IN (0,0, $_xmax,$_ymax, "rep.bmp", -1,90)
            $check_out = 1
            M_MOVE($_return1, $_return2)
            LCLICK($_xmouse,$_ymouse)
            WAITMS(RND(500,1000))
            M_MOVE($_return1+166,$_return2+244)
            LCLICK($_xmouse,$_ymouse)
            WAIT(RND(190,290))
         END_IF
      END_IF
   END_IF
END_IF
END_CYC
WAITMS(50)
GOTO(start)

[sslava2]

А готовый можно пет + корабль

[GhostBuster30]

А можешь архивом скинуть? А то не понятно что и куда вставлять((

[E.x.p.r.e.s.s.]

Цитата: Сообщение от GhostBuster30 А можешь архивом скинуть? А то не понятно что и куда вставлять((

держи

[GhostBuster30]

Я так понял он только кораблем собирает? Я включил ПЭТа а скрипт выключает его. А так, отличный скрипт))